Einer der umstrittensten Aspekte von Windows 10 ist die Entscheidung von Microsoft, Updates obligatorisch zu machen. Wenn Sie Windows 10 Pro -, Enterprise-oder Education-Editionen haben, können Sie Updates verschieben, aber Sie können sie nicht direkt ablehnen.

Wenn Sie unzufrieden mit Microsoft sind, das Updates ohne Ihr Mitspracherecht gewaltsam auf Ihrem System installiert, können Sie diese Funktion blockieren W10Privacy.

Wenn Sie noch nie von diesem Programm gehört haben es lohnt sich zu überprüfen out wie die Software gibt Ihnen die Kontrolle über Windows 10 viele Privatsphäre funktionen, so dass Sie das Betriebssystem Snooping auf, was Sie tun, zu verhindern. Optionen sind farbcodiert, so dass Sie auf einen Blick sehen können, ob etwas ist sicher zu ändern/deaktivieren oder nicht.

In W10Privacy 2, sie können das Programm jetzt so einstellen, dass es Windows 10 deaktiviert eigenen Update-Mechanismus und ersetzen Sie es durch seine eigenen. Benutzer können wählen die updates zu installieren, und die zu ignorieren. Das ist nicht etwas jeder sollte es tun, aber Sie können die Schritte leicht umkehren, sollten Sie müssen.

Bevor Sie diese Funktion verwenden können, müssen Sie einige zusätzliche Komponenten herunterladen. Folgen Sie diesen Schritten:

• Herunterladen W10Privacy 2 und entpacken Sie es in einen Ordner auf Ihrer Festplatte.
• Herunterladen PsExec (Teil von PsTools package) und in die W10Privacy kopieren Ordner.
• Laden Sie das [[6]}Windows Update PowerShell Modul von Technet herunter und entpacken Sie es in einen Unterordner im Ordner W10Privacy.
• Klicken Sie mit der rechten Maustaste auf W10Privacy.exe und wählen Sie Als Administrator ausführen aus dem Kontextmenü. Wählen Sie einen Systemwiederherstellungspunkt zu machen. Es lohnt sich auch eine vollständige Systemsicherung (nur für den Fall).
• Gehen Sie zu Extras > Windows Updates, um die Optionen zu verwalten. Es gibt sechs verschiedene Kontrollkästchen. Keine sind standardmäßig aktiviert. Sie werden:
• PSWindows Update Module existiert (muss vorher vom Benutzer bereitgestellt werden in den Ordner W10Privacy).
• PsExec.exe im Ordner W10Privacy (muss vom Benutzer bereitgestellt werden). W10Privacy Anpassung des PSWindows-Update Moduls.

• Konfigurieren Sie den WSUS-Server.

• W10Privacy befindet sich in einem Pfad/Ordner ohne Leerzeichen ein. Nicht betrachten Sie Treiber in der Update-Suche.

• Wenn Sie Updates manuell verwalten möchten, überprüfen Sie die erste fünf Option. Mit der sechsten Option können Sie entscheiden, ob Sie Treiber auflisten möchten neben updates. Das liegt an dir.
• Klicken Sie auf Set changed settings und dann auf Start checking for updates button und Sie werden alle neuen Updates, die noch angezeigt werden installiert und kann wählen, welche Maßnahmen zu ergreifen.

Sobald Sie für Ihre Updates verantwortlich sind, führen Sie die Software regelmäßig aus und überprüfen Sie, ob Sie keine wichtigen Informationen verpassen updates;

Credits:

1. So erhalten Sie die vollständige Kontrolle über die automatischen Updates von Windows 10

Mit Hilfe von @Ramhound habe ich herausgefunden, wie automatische Updates unter Windows 10 gestoppt werden können.

Bitte beachten Sie, dass dies für Windows 10 Pro gilt, da es sich um die von mir ausgeführte Version handelt.

Um die automatischen Updates zu stoppen, können Sie Folgendes tun:

1. Einstellungen öffnen
2. Klicken Sie auf Update & Sicherheit
3. Klicken Sie auf Advanced options
4. Stellen Sie sicher, dass die Option Defer upgrades aktiviert ist
5. Schließen Sie die Einstellungen Fenster-und das ist es du bist fertig!

Update -

Wie in den Kommentaren von @Vinayak erwähnt, ist die Defer-Option jetzt auch für Heimanwender verfügbar. Weitere Informationen hier

Für Windows 10 Heimanwender

, Versuchen Sie die folgende Methode aus Windows Central. Grundsätzlich deaktivieren Sie den Neustart-Dienst, nicht den Update-Dienst. Sie können dann neu starten, Wann immer Sie wollen. Bitte beachten Sie, dass Sie Administratorrechte benötigen, aber ich nehme an, Sie haben es bereits, da Sie Windows Home Edition verwenden.

1. Benennen Sie die Datei in einem Windows Explorer-Fenster um: C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator\Reboot (vorausgesetzt, Ihr %windir% ist C:\), um sie neu zu starten.alt. Hinweis, Sie werden hier wurde nach Administratorzugriff gefragt.
2. Erstellen Sie ein Verzeichnis mit dem Namen Reboot in C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator\. Dadurch wird verhindert, dass Windows eine Datei mit demselben Namen neu erstellt. Beachten Sie, dass Sie hier nach Administratorzugriff gefragt werden.
3. starten Sie den Computer neu. Dadurch werden alle Dienste zurückgesetzt und verhindert, dass der Neustartdienst gestartet wird.

Bitte beachten Sie, dass dies nicht von Microsoft gefördert wird. Aber dann wieder, weder steuern Sie eigenen Boot-Zeitplan, so nehmen, dass MS! Ernsthaft, wenn Sie nicht wissen, was Sie tun, verstehen Sie die Risiken, die Sie eingehen, indem Sie Anweisungen aus dem Internet befolgen. Dies ist sicherlich einfach genug, dass ein Verständnis von Windows 95 helfen würde, zu erklären, was hier passiert.

Massive Überarbeitung der vorherigen Batch-Dateien Toggle Suite in einzelnen Skript mit Best Practices blockieren!
Sehen Sie es in Aktion

Desktop-Rechtsklick-Kontextmenü dynamische Benutzeroberfläche mit Umschaltmöglichkeiten für alles!
Schalten Sie alle Blöcke ein/aus, Erneuern Sie (von Pastebin) oder deinstallieren Sie die Skriptoptionen

Hide / Unhide / Install Update-Listen mit Zähler!
Listen werden automatisch aktualisiert, wenn Windows würde dich über MusNotification nörgeln!

Unabhängig Block Build-Upgrades, automatische Installationen, Downloads, Service
IFEO sicheres Blockieren ohne destruktive Eigentumsänderungen, Löschen von Dateien oder Entfernen von Aufgaben

Fokus auf Defender-Updates, die unabhängig arbeiten
Wenn Sie Windows Mayhem automatische Updates ausschalten, wird die integrierte Schutzschicht nicht beeinträchtigt,
im Gegensatz zu anderen-DIY-Updates "Management"

Windows_update_toggle.BVT

@set @version=10.0 /* &title Windows Update Toggle
@echo off &set "verbose="
echo.
echo      ---------------------------------------------------------------------
echo     :                  Windows Update Toggle v10.0 final                  :
echo     :---------------------------------------------------------------------:
echo     :      Block/Enable Upgrades, Installs, Downloads(!), Service(!)      :
echo     :         Disable/Enable Reporting, Speech, SearchUI, Defender        :
echo     :        Hide/Unhide/Apply update lists with count and max size       :
echo     :       Preset for Defender updates and Store downloads working       :
echo     :                                                                     :
echo     :     Toggle from the comfort of Desktop right-click context menu     :
echo      ---------------------------------------------------------------------
echo.
:: AveYo, 2018-05-13

if %1.==. timeout /t 10 &call wscript /e:JScript "%~f0" runas setup &exit/b &rem : no arguments, run setup elevated
if %1.==shift. shift &shift &rem : if loaded by WScript, shift args to prevent loop and restore %0
if %1.==. echo ERROR! &timeout /t 5 &exit/b : must have at least one arg

:: Setup executable blocking via ifeo
set notifier=EOSNotify MusNotification
set upgrader=Windows10UpgraderApp Windows10Upgrade WindowsUpdateBox SetupHost setupprep
set installer=wuauclt
set reporter=wermgr wsqmcons DiagTrackRunner DiagnosticsHub.StandardCollector.Service CompatTelRunner
set speecher=SpeechRuntime SpeechModelDownload
set searcher=SearchUI

set "exe=%notifier% %upgrader% %installer% %reporter%"
set "noop=%SystemRoot%\system32\systray.exe"
set "ifeo=HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\Image File Execution Options"
set "menu=HKCR\DesktopBackground\shell\WUT"
set "f0=%SystemRoot%\windows_update_toggle.bat"
set "task=wscript.exe /e:JScript \"%f0%\" schtasks WUT"
set "DefMUS={MicrosoftUpdateServer|MMPC|InternalDefinitionUpdateServer}"
set "DefMMPC={MMPC|MicrosoftUpdateServer|InternalDefinitionUpdateServer}"
set ".=>nul 2>nul"
for /f "tokens=2 delims=1234567890" %%# in ('shutdown /?^|findstr /bc:"E"') do set "[T]=%%#" &rem : cosmetic usage in menus
if defined verbose (echo on &set ".=" &set "window=") else set "window=hide"
call :%~1 %2 %3 %4 %5 %6 %7 %8 %9 &rem : launch secondary functions below dinamically, passing next args
echo.
echo Done! Use the Desktop right-click context menu to toggle, renew or uninstall
if "%~1"=="setup" (pause) else if defined verbose timeout /t 5
exit/b : End of main script, functions below

:refresh context menu
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoBlock noblock
if "%noblock%"=="Enable" exit/b
call :reg_query "%menu%0pending" MUIVerb pending
if defined pending exit/b
for %%# in ("1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
reg add "%menu%0pending" /v MUIVerb /d "Pending.." /f %.%
reg add "%menu%0pending" /v SubCommands /d "" /f %.%
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoRefresh norefresh
if "%norefresh%"=="Disable" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
call :status SetupHost
reg add "%menu%\shell\3Upgrades"   /v MUIVerb /d "Upgrades %[T]% [setuphost]    %toggle%" /f %.%
reg add "%menu%\shell\3Upgrades\command" /ve /d "%task%\upgrades" /f %.%
call :status wuauclt
reg add "%menu%\shell\4Installs"   /v MUIVerb /d "Installs %[T]% [wuauclt]    %toggle%" /f %.%
reg add "%menu%\shell\4Installs\command" /ve /d "%task%\installs" /f %.%
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="[WUTblocked]" (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\5Downloads"  /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    %toggle%" /f %.%
reg add "%menu%\shell\5Downloads\command" /ve /d "%task%\downloads" /f %.%
for /f "tokens=3" %%# in ('sc qc wuauserv ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="rpcss[WUTblocked]" (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\6Service"    /v MUIVerb /d "Service ( ! ) %[T]% [wuauserv]    %toggle%" /f %.%
reg add "%menu%\shell\6Service\command" /ve /d "%task%\service" /f %.%
call :status wermgr
reg add "%menu%\shell\81Report"    /v MUIVerb /d "Report    %[T]% %toggle%" /f %.%
reg add "%menu%\shell\81Report\command" /ve /d "%task%\report" /f %.%
call :status SpeechRuntime
reg add "%menu%\shell\82Speech"    /v MUIVerb /d "Speech    %[T]% %toggle%" /f %.%
reg add "%menu%\shell\82Speech\command" /ve /d "%task%\speech" /f %.%
call :status SearchUI
reg add "%menu%\shell\83Search"    /v MUIVerb /d "SearchUI  %[T]% %toggle%" /f %.%
reg add "%menu%\shell\83Search\command" /ve /d "%task%\search" /f %.%
set "defstatus=if((Get-MpPreference).DisableRealtimeMonitoring){write-host stopped}else{write-host enabled}"
for /f "delims=" %%# in ('call powershell.exe -c "%defstatus%;"') do set "toggle=%%#"
reg add "%menu%\shell\84Defender"  /v MUIVerb /d "Defender  %[T]% %toggle%" /f %.%
reg add "%menu%\shell\84Defender\command" /ve /d "%task%\defender" /f %.%
if "%norefresh%"=="Enable" reg delete "%menu%0pending" /f %.%
exit/b

:toggle WUT
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoBlock noblock
if "%noblock%"=="Disable" (set "toggle=Enable") else set "toggle=Disable"
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "%toggle%" /f %.%
:: Generate WUT main context menu
for %%# in ("" "0pending" "1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
reg add "%menu%" /v MUIVerb /d "Windows Update Toggle" /f %.%
reg add "%menu%" /v Icon /d "appwiz.cpl,5" /f %.%
reg add "%menu%" /v SubCommands /d "" /f %.%
reg add "%menu%\shell\9Setup" /v MUIVerb /d "windows_update_toggle.bat v10.0" /f %.%
reg add "%menu%\shell\9Setup" /v SubCommands /d "" /f %.%
reg add "%menu%\shell\9Setup\shell\1Toggle" /v MUIVerb /d "%toggle%" /f %.%
reg add "%menu%\shell\9Setup\shell\2Renew"  /v MUIVerb /d "Renew" /f %.%
reg add "%menu%\shell\9Setup\shell\3Remove" /v MUIVerb /d "Remove" /f %.%
reg add "%menu%\shell\9Setup\shell\1Toggle\command" /ve /d "%task%\toggle" /f %.%
reg add "%menu%\shell\9Setup\shell\2Renew\command"  /ve /d "%task%\renew" /f %.%
reg add "%menu%\shell\9Setup\shell\3Remove\command" /ve /d "%task%\remove" /f %.%
if "%toggle%"=="Disable" (
 reg add "%menu%\shell\1Refresh" /v MUIVerb /d "Refresh" /f %.%
 reg add "%menu%\shell\1Refresh\command" /ve /d "%task%\refresh" /f %.%
 reg add "%menu%\shell\2Lists" /v MUIVerb /d "Hide / Unhide / Apply %[T]% enabled" /f %.%
 reg add "%menu%\shell\2Lists\command" /ve /d "%task%\lists" /f %.%
 reg add "%menu%\shell\7Repair"     /v MUIVerb /d "Troubleshooter" /f %.%
 reg add "%menu%\shell\7Repair\command" /ve /d "%task%\repair" /f %.%
)
:: Disabling automatic updates hinders Defender, so get definitions from MMPC first
if "%toggle%"=="Enable" ( set "DefSig=%DefMUS%" ) else set "DefSig=%DefMMPC%"
start "WUT:MpPref" wscript /e:JScript "%~f0" cmd "powershell.exe -c `Set-MpPreference -SignatureFallbackOrder %DefSig%;`"
:: Default services
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
:: Toggle ifeo exe blocking
for %%# in (%exe% %speech% %search%) do reg delete "%ifeo%\%%#.exe" /f %.%
if "%toggle%"=="Enable" exit/b WUT disabled, so skip the code below
for %%# in (%exe%) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
:: WUTRefresh hijacking
for %%# in (MusNotification EOSNotify) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.%
call :refresh menu
exit/b

:hide update
echo %0 %*
call :reg_query "%menu%1hide\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
call wscript /e:JScript "%f0%" hide "%updatefound%"
exit/b

:unhide update
echo %0 %*
call :reg_query "%menu%2unhide\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
call wscript /e:JScript "%f0%" unhide "%updatefound%"
exit/b

:apply update
echo %0 %*
call :reg_query "%menu%3apply\shell\%~1" MUIVerb updatefound
echo -%updatefound%
if not defined updatefound exit/b
:: Temporarily unblock downloads and installs
call :reg_query "%ifeo%\wuauclt.exe" Debugger installs_blocked
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "downloads_blocked=%%#"
call wscript /e:JScript "%f0%" apply "%updatefound%"
:: Restore block
if defined installs_blocked reg add "%ifeo%\wuauclt.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "wuauclt.exe" /t /f %.%
if defined downloads_blocked sc config TrustedInstaller type= own depend= [WUTblocked] %.%
exit/b

:lists
echo %0 %*
call :reg_query "HKLM\SOFTWARE\WUT.bat" NoRefresh norefresh
if "%norefresh%"=="Disable" ( set "norefresh=Enable" &set "toggle=disabled") else set "norefresh=Disable" &set "toggle=enabled"
reg add "HKLM\SOFTWARE\WUT.bat" /v NoRefresh /d "%norefresh%" /f %.%
reg add "%menu%\shell\2Lists" /v MUIVerb /d "Hide / Unhide / Apply %[T]% %toggle%" /f %.%
reg add "%menu%\shell\1Refresh" /v MUIVerb /d "Refresh" /f %.%
reg add "%menu%\shell\1Refresh\command" /ve /d "%task%\refresh" /f %.%
if "%norefresh%"=="Enable" (
 reg delete "%menu%0pending" /f %.% &reg delete "%menu%1hide" /f %.% &reg delete "%menu%2unhide" /f %.%
 reg delete "%menu%3apply" /f %.% &reg delete "%menu%\shell\1Refresh" /f %.%
)
call :refresh lists
exit/b

:upgrades
echo %0 %*
call :flip SetupHost
reg add "%menu%\shell\3Upgrades"   /v MUIVerb /d "Upgrades %[T]% [setuphost]    %toggle%" /f %.%
for %%# in (%upgrader%) do if defined block (
 reg delete "%ifeo%\%%#.exe" /f %.%
) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:installs
echo %0 %*
call :flip wuauclt
reg add "%menu%\shell\4Installs"   /v MUIVerb /d "Installs %[T]% [wuauclt]    %toggle%" /f %.%
for %%# in (%installer%) do if defined block (
 do reg delete "%ifeo%\%%#.exe" /f %.% &start "wt" wscript /e:JScript "%f0%" WUTRefresh
) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:downloads
echo %0 %*
call :reg_query "%menu%3apply" MUIVerb pending
set "reboot=%pending:reboot=%"
if defined pending if "%pending%"=="%reboot%" set "pending="
if defined pending (
 sc config TrustedInstaller type= own depend= / %.%
 reg add "%menu%\shell\5Downloads" /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    reboot?" /f %.%
 exit/b
)
for /f "tokens=3" %%# in ('sc qc TrustedInstaller ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="[WUTblocked]" (set "blocked=/") else set "blocked=[WUTblocked]"
net stop TrustedInstaller /y %.%
for /f "tokens=3" %%# in ('sc queryex TrustedInstaller ^| find /i "PID"') do set "pid=%#"
if not "%pid%"=="0" taskkill /pid %pid% /f %.%
sc config TrustedInstaller type= own depend= %blocked% %.%
tasklist /svc | find /i "TrustedInstaller" %.%
if errorlevel 1 net start TrustedInstaller /y %.%
if errorlevel 1 (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\5Downloads" /v MUIVerb /d "Downloads ( ! ) %[T]% [trustedinstaller]    %toggle%" /f %.%
if "%toggle%"=="enabled" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
exit/b

:service
echo %0 %*
for /f "tokens=3" %%# in ('sc qc wuauserv ^| find /I "WUTblocked"') do set "blocked=%%#"
if /i "%blocked%"=="rpcss[WUTblocked]" (set "blocked=rpcss") else set "blocked=rpcss[WUTblocked]"
net stop wuauserv /y %.%
for /f "tokens=3" %%# in ('sc queryex wuauserv ^| find /i "PID"') do set "pid=%#"
if not "%pid%"=="0" taskkill /pid %pid% /f %.%
sc config wuauserv type= share depend= %blocked% %.%
tasklist /svc | find /i "wuauserv" %.%
if errorlevel 1 net start wuauserv /y %.%
if errorlevel 1 (set "toggle=blocked") else set "toggle=enabled"
reg add "%menu%\shell\6Service" /v MUIVerb /d "Service ( ! ) %[T]% [wuauserv]    %toggle%" /f %.%
if "%toggle%"=="enabled" start "WUT" wscript /e:JScript "%f0%" WUTRefresh
exit/b

:repair
echo %0 %*
:: Restore services (undo only the changes made by this script, not whatever blocking was done by other means)
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
:: Remove any IFEO blocking done by past scripts
set eo=DiagnosticsHub.StandardCollector.Service WindowsUpdateElevatedInstaller LocationNotificationWindows InstallAgentUserBroker
set eo=%eo% UpdateNotificationMgr DataUsageLiveTileTask Windows10UpgraderApp WindowsActionDialog SpeechModelDownload WerFaultSecure
set eo=%eo% GetCurrentRollback WindowsUpdateBox Windows10Upgrade TrustedInstaller MusNotification DiagTrackRunner CompatTelRunner
set eo=%eo% WinREBootApp64 WinREBootApp32 UNPUXLauncher SpeechRuntime MusNotifyIcon PilotshubApp InstallAgent dstokenclean wsqmcons
set eo=%eo% disksnapshot osrssupdate wuapihost WaaSMedic UsoClient UNPUXHost SIHClient setupprep SetupHost osrssinst EOSNotify wusa
set eo=%eo% WerFault TiWorker SearchUI DWTRIG20 dusmtask dmclient appidtel wuauclt wermgr DFDWiz remsh reach HxTsr DWWIN DW20 GWX
for %%# in (%eo%) do reg delete "%ifeo%\%%#.exe" /f %.%
:: Restore notification hijacking
>"%SystemRoot%\WUTRefresh.bat" echo/@start "WUTRefresh" /min wscript.exe /e:JScript "%f0%" WUTRefresh
for %%# in (MusNotification EOSNotify) do reg add "%ifeo%\%%#.exe" /v Debugger /d "%SystemRoot%\WUTRefresh.bat" /f %.%
:: Remove pending instance safeguard
reg delete "HKLM\SOFTWARE\WUT.bat" /v Pending /f %.%
:: Refresh menu
call :refresh repair
:: Open Update Diagnostic
start "wud" msdt.exe /id WindowsUpdateDiagnostic %.%
:: Open official update troubleshooter page
start https://support.microsoft.com/en-us/help/4027322/windows-update-troubleshooter %.%
exit/b

:report
echo %0 %*
call :flip wermgr
reg add "%menu%\shell\81Report"    /v MUIVerb /d "Report    %[T]% %toggle%" /f %.%
for %%# in (%reporter%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:speech
echo %0 %*
call :flip SpeechRuntime
reg add "%menu%\shell\82Speech"    /v MUIVerb /d "Speech    %[T]% %toggle%" /f %.%
for %%# in (%speecher%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:search
echo %0 %*
call :flip SearchUI
reg add "%menu%\shell\83Search"    /v MUIVerb /d "SearchUI  %[T]% %toggle%" /f %.%
for %%# in (%searcher%) do if defined block ( reg delete "%ifeo%\%%#.exe" /f %.% ) else (
 reg add "%ifeo%\%%#.exe" /v Debugger /d "%noop%" /f %.% &taskkill /im "%%#.exe" /t /f %.%
)
exit/b

:defender
echo %0 %*
set "s10=$t=1;$toggle='stopped'; if((Get-MpPreference).DisableRealtimeMonitoring){$t=0;$toggle='enabled';}"
set "s11=Set-MpPreference -DisableRealtimeMonitoring $t"
set "s12=Set-MpPreference -DisableBehaviorMonitoring $t"
set "s13=Set-MpPreference -DisableIOAVProtection $t"
set "s14=write-host $toggle"
for /f "delims=" %%# in ('call powershell.exe -c "%s10%;%s11%;%s12%;%s13%;%s14%;"') do set "toggle=%%#"
reg add "%menu%\shell\84Defender"  /v MUIVerb /d "Defender  %[T]% %toggle%" /f %.%
exit/b

:update_defender - triggered from WScript to get definitions from MMPC, regardless of updates being blocked
tasklist /FI "IMAGENAME eq MpCmdRun.exe" | find ".exe" %.%
if not errorlevel 1 exit/b
pushd %ProgramFiles%\Windows Defender
call MpCmdRun.exe -removedefinitions -dynamicsignatures
call MpCmdRun.exe -SignatureUpdate -MMPC
exit/b

:setup
echo %0 %*
pushd %SystemRoot%
if /i "%~f0"=="%f0%" (set "initial_setup=") else copy /y "%~f0" "%f0%" %.%
:: Create WUTUndo for emergencies
 >WUTUndo.bat echo/pushd %%~dp0system32\config
>>WUTUndo.bat echo/reg load HKLM\WUTUndo1 SOFTWARE
>>WUTUndo.bat echo/set "koff=HKLM\WUTUndo1\Microsoft\Windows NT\CurrentVersion\Image File Execution Options" ^&set "kon=%ifeo%"
>>WUTUndo.bat echo/for %%%%B in (%exe%) do for %%%%K in ("%%koff%%" "%%kon%%") do reg delete "%%%%~K\%%%%B.exe" /f 2^>nul
>>WUTUndo.bat echo/reg unload HKLM\WUTUndo1
>>WUTUndo.bat echo/reg load HKLM\WUTUndo2 SYSTEM
>>WUTUndo.bat echo/for %%%%K in (WUTUndo2 SYSTEM) do (
>>WUTUndo.bat echo/ reg delete "HKLM\%%%%~K\ControlSet001\Services\TrustedInstaller" /v DependOnService /f 2^>nul
>>WUTUndo.bat echo/ reg delete "HKLM\%%%%~K\CurrentControlSet\Services\TrustedInstaller" /v DependOnService /f 2^>nul
>>WUTUndo.bat echo/)
>>WUTUndo.bat echo/reg unload HKLM\WUTUndo2
:: Create WUTRefresh to hijack update notifications and refresh context menu in addition to preventing forced reboots
>WUTRefresh.bat echo/@start "WUTRefresh" /min wscript.exe /e:JScript "%f0%" WUTRefresh
:: Create tasks to run context menu entries with proper access and no output window
start "WUT" wscript /e:JScript "%~f0" cmd "call `%~f0` setup_schtasks"
:: WUT options
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "Enable" /f %.%
call :toggle blocking
exit/b

:setup_schtasks - no stalling separate process
set "strun=wscript.exe /e:JScript \"%f0%\" run%window%"
for %%t in (refresh lists upgrades installs downloads service repair report speech search defender toggle renew remove) do (
 schtasks /create /ru "%username%" /sc once /tn "WUT\%%t" /tr "%strun% %%t" /st "00:00:00" /it /rl highest /f %.%
)
for %%t in (hide unhide apply) do for /l %%n in (101,1,116) do (
 schtasks /create /ru "%username%" /sc once /tn "WUT\%%t\%%n" /tr "%strun% %%t %%n" /st "00:00:00" /it /rl highest /f %.%
)
exit/b

:renew
echo %0 %*
echo Renewing from internet - old version saved as %SystemRoot%\WUT.old
pushd %SystemRoot%
if exist WUT.new del /f /q WUT.new %.%
call wscript /e:JScript "%~f0" renew "https://pastebin.com/raw/gNsLEWJe" "%SystemRoot%\WUT.new"
if exist WUT.new copy /y "%f0%" WUT.old %.% &copy /y WUT.new "%f0%" %.% &del /f /q WUT.new %.%
start "WUT" "%f0%" setup renew %.%
exit/b

:remove
echo %0 %*
for %%# in (NoBlock NoRefresh) do reg add "HKLM\SOFTWARE\WUT.bat" /v %%# /d "Disable" /f %.%
call :toggle off
reg delete "HKLM\SOFTWARE\WUT.bat" /f %.%
for %%# in ("" "0pending" "1hide" "2unhide" "3apply") do reg delete "%menu%%%~#" /f %.%
for %%t in (refresh lists upgrades installs downloads service repair report speech search defender toggle renew remove) do (
 schtasks /delete /tn "WUT\%%t" /f %.%
)
for %%t in (hide unhide apply) do for /l %%n in (101,1,116) do schtasks /delete /tn "WUT\%%t\%%n" /f %.%
for %%t in (hide unhide apply) do schtasks /delete /tn "WUT\%%t" /f %.%
schtasks /delete /tn "WUT" /f %.%
sc config wuauserv type= share depend= rpcss %.%
sc config TrustedInstaller type= own depend= / %.%
pushd %SystemRoot%
del /f /q WUT.bat WUT.old DefenderManualUpdate.bat WUTRefresh.bat WUTUndo.bat "%f0%" %.%
exit/b

:flip %1:exe
call :reg_query "%ifeo%\%~1.exe" Debugger block
if defined block (set "toggle=enabled") else set "toggle=blocked"
exit/b

:status %1:exe
call :reg_query "%ifeo%\%~1.exe" Debugger block
if defined block (set "toggle=blocked") else set "toggle=enabled"
exit/b

:reg_query %1:KeyName %2:ValueName %3:OutputVariable %4:other_options[example: "/t REG_DWORD"]
setlocal & for /f "skip=2 delims=" %%s in ('reg query "%~1" /v "%~2" /z 2^>nul') do set "rq=%%s" & call set "rv=%%rq:*)    =%%"
endlocal & set "%~3=%rv%" & exit/b &rem                                         AveYo: call :reg_query "HKCU\MyKey" "MyValue" MyVar

::---------------------------------------------------------------------------------------------------------------------------------
:JScript_functions                                                                 AveYo: Switch syntax highlighter to 'javascript'
::-------------------------------------------------------------------------------------------------------------------------------*/
f0=WSH.ScriptFullName; run=WSH.Arguments(0); args=''; for(i=1;i<WSH.Arguments.length;i++) args+=' "'+WSH.Arguments(i)+'"';
function sex(exe,args){WSH.CreateObject('Shell.Application').ShellExecute(exe,args,'','',0);}; function reg(s){ sex('reg.exe',s); }

// Open external commands in new hidden cmd instance - backquotes replaced to quotes
if (run=='cmd') sex('cmd','/c '+args.replace(/`/g,'"'));

// Context menu entries trigger - elevated with no popups
if (run=='schtasks') sex('SCHTASKS.EXE','/Run /TN '+args);

// Shift to CMD if loaded by WScript - pass arguments, prevent loop, run as admin at setup, hide window at context-menu
function cmd(adm,win){WSH.CreateObject('Shell.Application').ShellExecute('cmd','/c call "'+f0+'" shift "'+f0+'"'+args,'',adm,win);}
if (run=='run') cmd('',1); if (run=='runhide') cmd('',0); if (run=='runas') cmd('runas',1); if (run=='runashide') cmd('runas',0);

if (run=='renew') {
  // renew script over internet
  try{
  downloader=WSH.CreateObject("WinHttp.WinHttpRequest.5.1");
  if (downloader===null) downloader=WSH.CreateObject("WinHttp.WinHttpRequest");
  if (downloader===null) downloader=WSH.CreateObject("MSXML2.ServerXMLHTTP");
  if (downloader===null) downloader=WSH.CreateObject("Microsoft.XMLHTTP");
  downloader.Open("GET",WSH.Arguments(1),false); downloader.Send(); oASI=downloader.ResponseBody(); downloader=undefined;
  oASO=WSH.CreateObject("ADODB.Stream"); oASO.type=1; oASO.Mode=3; oASO.Open; oASO.Write(oASI); oASI=undefined;
  oASO.SaveToFile(WSH.Arguments(2)); oASO.Close();
  }catch(e){} // supress all errors since we're working with com objects
}

// WUT Hide/Unhide/Apply lists
if (run=='WUTRefresh' || run=='hide' || run=='unhide' || run=='apply') {
  SRP=GetObject("winmgmts:StdRegProv"); pending=SRP.GetStringValue(2147483650,'SOFTWARE\\WUT.bat','Pending');
  if (pending===0) WSH.quit(); else SRP.SetStringValue(2147483650,'SOFTWARE\\WUT.bat','Pending','yes'); // prevent instances
  k='HKCR\\DesktopBackground\\shell\\WUT'; hk=k+'1hide'; uk=k+'2unhide'; ik=k+'3apply'; pk=k+'0pending';           // set list keys
  reg('delete "'+hk+'" /f'); reg('delete "'+uk+'" /f'); reg('delete "'+ik+'" /f');                               // delete previous
  reg('add "'+pk+'" /v MUIVerb /d "Pending.." /f'); reg('add "'+pk+'" /v SubCommands /d "" /f');             // add Pending.. entry
  // Check for updates
  count=0; wuthide=[]; wutunhide=[];
  try{
  session=WSH.CreateObject("Microsoft.Update.Session"); reboot=WSH.CreateObject("Microsoft.Update.SystemInfo").RebootRequired;
  searcher=session.CreateUpdateSearcher();
  sresult=searcher.Search("IsInstalled=0"); Updatelist=sresult.Updates; count=sresult.Updates.Count;
  for(i=0;i<count;i++) {
    itemTitle=Updatelist.Item(i).Title;
    minsize=Updatelist.Item(i).MinDownloadSize; maxsize=Updatelist.Item(i).MaxDownloadSize; wutsize='';
    if (maxsize > 1073741824) wutsize=' ['+Math.round(minsize/10737418.24)/100+' - '+Math.round(maxsize/10737418.24)/100+'GB]';
    else if (maxsize > 1048576) wutsize=' ['+Math.round(minsize/10485.76)/100+' - '+Math.round(maxsize/10485.76)/100+'MB]';
    else if (maxsize > 1024) wutsize=' ['+Math.round(minsize/10.24)/100+' - '+Math.round(maxsize/10.24)/100+'KB]';
    else if (maxsize > 0) wutsize=' ['+(minsize)+' - '+(maxsize)+'B]';
    wutTitle=Updatelist.Item(i).Title + wutsize;
    if (run=='apply' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      // Add matching entry to UpdateColl
      UpdateColl=WSH.CreateObject("Microsoft.Update.UpdateColl"); UpdateColl.Add(Updatelist.Item(i));
      // Download update
      downloader=session.CreateUpdateDownloader(); downloader.Updates=UpdateColl; dresult=downloader.Download();
      if (dresult.ResultCode==2) {
        // Unblock apply
        sex('sc','config TrustedInstaller type= own depend= /');
        KeyPath='SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion\\Image File Execution Options\\wuauclt.exe';
        SRP.DeleteKey(2147483650,KeyPath);
        WSH.Sleep(1000);
        //Apply update
        installer=session.CreateUpdateInstaller(); installer.Updates=UpdateColl; iresult=installer.Install();
        if (iresult.ResultCode==2) continue;
      }
    }
    // hide and unhide are very simple bool flip compared to apply
    if (run=='hide' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      Updatelist.Item(i).IsHidden=true; wutunhide.push(wutTitle); continue;
    }
    if (run=='unhide' && WSH.Arguments(1).indexOf(itemTitle) > -1) {
      Updatelist.Item(i).IsHidden=false; wuthide.push(wutTitle); continue;
    }
    // Trigger :update_defender to manually refresh definitions from MMPC
    if (Updatelist.Item(i).IsHidden===false && itemTitle.indexOf('(Definition') > -1) {
      sex('cmd','/c call "'+f0+'" update_defender');
    }
    // Sorting lists
    if (Updatelist.Item(i).IsHidden) wutunhide.push(wutTitle); else wuthide.push(wutTitle);
  }
  // Generate Hide context menu
  if (wuthide.length>0){
    for(i=101,n=wuthide.length+101;i<n;i++) {
      reg('add "'+hk+'\\shell\\'+i+'" /v MUIVerb /d "'+wuthide[i-101]+'" /f');
      reg('add "'+hk+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\hide\\'+i+'" /f');
    }
    reg('add "'+hk+'" /v SubCommands /d "" /f');
    reg('add "'+hk+'" /v MUIVerb /d "Hide '+"\t"+wuthide.length+'" /f');
  }
  // Generate Unhide context menu
  if (wutunhide.length>0){
    for(i=101,n=wutunhide.length+101;i<n;i++) {
      reg('add "'+uk+'\\shell\\'+i+'" /v MUIVerb /d "'+wutunhide[i-101]+'" /f');
      reg('add "'+uk+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\unhide\\'+i+'" /f');
    }
    reg('add "'+uk+'" /v SubCommands /d "" /f');
    reg('add "'+uk+'" /v MUIVerb /d "Unhide '+"\t"+wutunhide.length+'" /f');
  }
  // Generate Apply context menu
  if (wuthide.length>0){
    for(i=101,n=wuthide.length+101;i<n;i++) {
      reg('add "'+ik+'\\shell\\'+i+'" /v MUIVerb /d "'+wuthide[i-101]+'" /f');
      reg('add "'+ik+'\\shell\\'+i+'\\command" /ve /d "wscript.exe /e:JScript \\"'+f0+'\\" schtasks WUT\\apply\\'+i+'" /f');
    }
    reg('add "'+ik+'" /v SubCommands /d "" /f');
    reg('add "'+ik+'" /v MUIVerb /d "Apply '+"\t"+((reboot) ? 'must reboot' : wuthide.length)+'" /f');
  }
  }catch(e){} // supress all errors since we're working with com objects
  reg('delete "'+pk+'" /f'); SRP.DeleteValue(2147483650,'SOFTWARE\\WUT.bat','Pending'); // Remove Pending.. temporary entry
}
//

Zuletzt aktualisiert für v10.0 endgültig. Up-to-date-code auf pastebin link oben.

Der Status von Windows Update-ab 2019

Microsoft hat große Anstrengungen unternommen, um Windows Update unvermeidlich zu machen, deshalb funktionieren die traditionellen Methoden nicht mehr oder nur noch für eine begrenzte Zeit.

Microsoft hat Systemdienste hinzugefügt, die nicht deaktiviert werden können. Zweck ist es, Windows zu aktualisieren. Chef unter diesen ist der Orchestrator-Dienst aktualisieren, beauftragt mit dem Herunterladen, Installieren und Überprüfen der Updates. Wenn gestoppt, die computer kann die Updates nicht mehr herunterladen und installieren, aus diesem Grund kann es nur für die aktuelle Sitzung deaktiviert werden und wird beim nächsten Neustart wieder aktiviert.

Der Dienst, der damit beauftragt ist, Windows Update unaufhaltsam zu machen, ist der neue Windows Update Medic-Dienst, beauftragt mit Windows Update funktionsfähig zu halten. Es ist dieser Dienst, der alle traditionellen Methoden zum Blockieren rückgängig macht Windows Update, so dass man periodisch und unerwartet herausfindet, dass der Windows Update-Einstellungen wurden auf ihre ursprünglichen Werte zurückgesetzt und das Windows ist zurückgegangen, um Updates für den Benutzer zu erzwingen.

Der Windows Update Medic-Dienst selbst kann überhaupt nicht deaktiviert werden. Jeder Versuch, dies zu tun, endet mit der Meldung "Zugriff verweigert".

Dennoch gibt es ein Produkt eines Drittanbieters, das vollständig blockieren kann Windows Update: Windows Update Blocker - . Dieses kostenlose Produkt ist portabel und kann Windows Update mit einem Klick deaktivieren/aktivieren. In tatsache, es kann auch jeden anderen nicht blockierbaren Windows-Dienst blockieren. Es wird berichtet, dass es 2018 noch funktioniert.

Die Verwendung eines Drittanbieterprodukts kann auf lange Sicht sicherer sein, als sich darauf zu verlassen Windows semi-dokumentierte Funktionen, die sich ohne vorherige Ankündigung ändern können. Einige weitere kostenlose Produkte finden Sie in diese Antwort von mir, die die Windows-API verwenden, mit der jedes Programm ein Veto einlegen kann drohende Abschaltung.

Endlich eine dauerhafte Lösung gefunden, die nur funktioniert

Nachdem ich buchstäblich jeden Trick im Buch ausprobiert habe, wurde ich immer von Windows Update bested. Ich habe hier jede Lösung ausprobiert und jede Menge andere Quellen, und Windows hat ständig Wege gefunden, meine Pläne zu vereiteln.

Bis vor etwa 6 Monaten...

Ich habe eine dauerhafte Lösung gefunden, um ALLE Windows-Updates FÜR IMMER zu deaktivieren, unabhängig davon, ob der Dienst oder etwas anderes laufen. Ich habe diese Methode mit Hilfe vieler verschiedener Quellen herausgefunden, die mit vielen verschiedenen Dingen zu tun hatten. Insgesamt fand ich diese Methode selbst mit der Verwendung von Bits und Teilen anderer Informationen, die verwendet wurden, um Dinge zu tun, die nicht alle damit zusammenhängen, aber es funktioniert. Und es funktioniert absolut wunderschön.

1. Install Install DNS Proxy from hier

Es ist im Grunde eine aufgemotzte Version des Windows hosts-Datei, mit der Sie Funktionen wie Platzhalter hinzufügen können, was in unserem Fall aufgrund der vielen Quellen erforderlich ist, aus denen Windows seine Updates erhält.

1. Folgen Sie den Anweisungen hier damit Acryl seine Arbeit in Win 10 erledigt. Ziemlich einfaches Zeug.

2. Gehen Sie zu Ihrem Startmenü und klicken Sie unter Allen angezeigten Programmen auf " Die Hosts-Datei bearbeiten" hier

3. Fügen Sie diese Zeilen zum unteren Rand von die Hosts-Datei, ohne # Zeichen vor.

0.0.0.0 windowsupdate.microsoft.com
0.0.0.0 *.windowsupdate.microsoft.com
0.0.0.0 *.update.microsoft.com
0.0.0.0 windowsupdate.com
0.0.0.0 *.windowsupdate.com
0.0.0.0 download.windowsupdate.com
0.0.0.0 download.microsoft.com
0.0.0.0 *.download.windowsupdate.com
0.0.0.0 wustat.windows.com
0.0.0.0 ntservicepack.microsoft.com
0.0.0.0 stats.microsoft.com

Nun sollte der untere Teil der Datei so aussehen dies. Speichern und schließen Sie die Datei.

1. Öffnen Sie den Task-Manager, gehen Sie zur Registerkarte Dienste, klicken Sie unten auf "Dienste öffnen", wählen Sie > DNS-Proxy und klicken Sie auf diese Taste mit dem roten Kreis, um den Dienst neu zu starten.

FERTIG

Jetzt sollte dein Acrylkumpel deinen Rücken haben und ständig ein Auge behalten auge auf Microsofts Big Brother Taktik, um sicherzustellen, dass sie nicht die alten Sie zwingen können, Updates zu installieren, die Ihren PC komplett durcheinander bringen, die sie mindestens ein Viertel der Zeit haben, die sie es sowohl auf meinem Heim-PC als auch auf meinem[9]}Surface Pro getan haben welches soll der PC sein, der für Windows gebaut wurde, oder??? Cmon, Microsoft!

1. Überprüfen Sie, ob es funktioniert, indem Sie eine der Websites im obigen Code aufrufen. Öffnen Sie cmd und geben Sie

Ping windowsupdate.microsoft.com

Wenn diese sind Ihre Ergebnisse, werden Sie von nun an golden sein!!

Hinweis: Nach meiner Erfahrung hat dies meinen PC überhaupt nicht verlangsamt. Es leitet auch keinen Internetverkehr um, außer Anfragen an die Quellen, die Windows zum Aktualisieren oder Überprüfen auf Updates verwendet, so ähnlich wie die Hosts-Datei. Es verwendet auch im Grunde das gleiche Format wie die Hosts-Datei. Dies hat auch erfolgreich die Neuinstallation von Junk deaktiviert, dass Windows hält platzieren auf meinem Computer, der diesen riesigen farbigen Bildschirm gibt, der so etwas wie "Sie müssen aktualisieren, sonst wird Ihr Computer implodieren"sagt. Offensichtlich erinnere ich mich nicht, was die Warnung gesagt hat, seit es so lange her ist, dass ich es bekommen habe (aufgrund der vollständig erfolgreichen Blockierung vor 6 Monaten oder so), aber es war das Ärgerlichste, was ich je gesehen habe.

Update-Dienst deaktivieren

1. Win+R - > services.msc
2. Doppelklicken Sie auf Windows Update und ändern Sie den Starttyp in Deaktiviert. Um erneut zu aktivieren, kehren Sie zu Diensten zurück und ändern Sie sie in Automatisch.

Quelle: So steuern Sie Windows 10-Updates

In meinem Fall möchte ich nicht nur steuern, wann Windows-Updates ausgeführt werden, sondern auch, dass alle installierten Anwendungen bei ihren Online-Updates außer Kontrolle geraten.

Meine einfache One-Stop-Lösung ist also : 1. Bloc den Internetzugang für den Host auf Router-Seite. Keines der auf dem Host installierten Programme oder Dienste kann auf das Internet zugreifen. Of-cause Windows Updates ist auch blockiert.

1. Installieren Sie einen Squid-Proxyserver im lokalen Netzwerk und geben Sie den Proxy an die Anwendungen weiter, die Sie zulassen sie zu gehen Internet. Setzen Sie den Proxy nicht auf die Systemsteuerung / Internetoption, da dies der globale OS - weite Proxy ist, der den Schritt 1 überhaupt ungültig macht.

Die meisten Anwendungen unterstützen pro anwendungsbasierte Proxy-Einstellung, wie Chrome, Firefox, alle Arten von Spielen usw.

1. Für Anwendungen, die die lokale Proxy-Einstellung nicht unterstützen, verwenden Sie NAS Cloud falten als Cloud-Proxy. Beispielsweise unterstützt Office 365 Suits keinen Pro-Programm-Proxy. Anschließend können Sie eine NAS Cloud Sync einrichten (für beispiel: Synology NAS verfügt über Cloud Sync (OneDrive synchronisieren), um Conents in einer NAS-Falte zu synchronisieren, und Sie verwenden diese Falte als lokale Falte von Office 365. Zusätzliche Vorteile dieser Methode sind, dass Sie bei großen Dateien sehr schnell reagieren, da Sie die lokale Netzwerkgeschwindigkeit für den Zugriff auf OneDrive verwenden.

Auf diese Weise wird der Internetzugang Ihres Computers stark von Ihnen selbst kontrolliert, niemand kann Sie durcheinander bringen.

Wenn Sie Windows aktualisieren möchten, legen Sie die Option Systemsteuerung | Internet fest, um Ihre lokale proxy, daher kann Windows Ihr Betriebssystem aktualisieren. Schalten Sie danach den globalen Proxy sofort aus, um Ihren Computer wieder in eine ruhige, ruhige Welt zu versetzen.

2 Jahre später und Milliarden von nicht gespeicherten Werken, die durch den Update-Mechanismus von Microsoft verloren gehen, gibt es endlich ein großes Update, das das Problem löst.

Windows 10 Creators Update jetzt verfügbar (Direkter Download)

Nach der Installation des Updates wird der Benutzer endlich wieder gefragt (wie die unbedeutenden 20+ Jahre zuvor), ob er möchte, dass das Update angewendet wird:

Manchmal frage ich mich, wer hinter diesen Entscheidungen steht...

Nach dem Update haben Sie weitere Optionen bezüglich der Aktualisierungszeiten. Um sie zu stoppen, gehen Sie zu Windows Update-Einstellungen > Erweiterte Optionen > Updates anhalten > AUF.

Unter Neustartoptionen finden Sie auch eine neue Option für Update-Benachrichtigungen:

Während ich Update im Dienste-und Gruppenrichtlinieneditor deaktiviert habe, wird es von Zeit zu Zeit wieder eingeschaltet. Dann muss ich sie manuell in Diensten ausschalten. Dies über die GUI zu tun ist mühsam, daher habe ich ein Batch-Skript geschrieben. Es stoppt und deaktiviert Background Intelligent Transfer Service und Windows Update.

@echo off

net stop wuauserv
net stop BITS

sc config wuauserv start= disabled
sc config BITS start= disabled

pause

Ich verwende auch (nicht speziell dafür) ein leichtes Netzwerkmonitor-Tool (Bandbreitenmonitor), damit ich weiß, wann es eine Aktivität gibt (ein Symbol in der Taskleiste). Wenn ich eine Aktivität sehe, bei der es keine geben sollte, weiß ich Windows Update wieder eingeschaltet. Dann führe ich das Skript aus und es ist aus.

Zum Deaktivieren von Windows-Updates müssen Sie Folgendes deaktivieren:

• Windows Update (wuauserv)
• Windows Update Medic-Dienst (WaaSMedicSvc)
• Microsoft Update-Orchestrator-Dienst (UsoSvc)

Und möglicherweise diese Aufgabe:

schtasks /Change /TN "Microsoft\Windows\WindowsUpdate\Automatic App Update" /Disable

Die Dinge ändern sich mit jeder Windows-Version, aber ich denke, diese sollten es tun. Um die Startoption der Dienste in Deaktiviert zu ändern, benötigen Sie entsprechende Berechtigungen in der Registrierung (Sie können dies nicht manuell über die GUI der Dienste tun). Sie können holen Sie sich die erforderlichen Berechtigungen mit SetACL Werkzeug. Startparameter für Dienste in der Registrierung finden Sie in HKEY_LOCAL_MACHINE\SYSTEM\CurrentControlSet\Services. Der Wert für "deaktiviert" ist dword:4.

Hier ist die Lösung für Windows 10 Home:

Https://github.com/WereDev/Wu10Man

Dies ist auf dem neuesten Stand (2020) Open-Source-Programm, das die Windows deaktivieren können Update-service.

Deaktivieren Sie alle windows-updates von PowerShell -

(PowerShell als Administrator ausführen)

Clear-Host

$WindowsUpdatePath = "HKLM:SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\"
$AutoUpdatePath = "HKLM:SOFTWARE\Policies\Microsoft\Windows\WindowsUpdate\AU"

If(Test-Path -Path $WindowsUpdatePath) {
    Remove-Item -Path $WindowsUpdatePath -Recurse
}

New-Item $WindowsUpdatePath -Force
New-Item $AutoUpdatePath -Force

Set-ItemProperty -Path $AutoUpdatePath -Name NoAutoUpdate -Value 1

Get-ScheduledTask -TaskPath "\Microsoft\Windows\WindowsUpdate\" | Disable-ScheduledTask

takeown /F C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator /A /R
icacls C:\Windows\System32\Tasks\Microsoft\Windows\UpdateOrchestrator /grant Administrators:F /T

Get-ScheduledTask -TaskPath "\Microsoft\Windows\UpdateOrchestrator\" | Disable-ScheduledTask

Stop-Service wuauserv
Set-Service wuauserv -StartupType Disabled

Write-Output "All Windows Updates were disabled"