abhilfe für ein kein Scrollrad Trackball?

Wenn Sie unter Windows sind, würde ich vorschlagen, AutoHotkey auszuprobieren, andere Benutzer haben das Scrollen bereits mit der Marmormaus in Angriff genommen (ich habe das Skript unten verwendet):

Http://www.autohotkey.com/board/topic/4677-wheel-button-emulation-script/

Logitechs Lösung, die mit ihren Treibern geliefert wird, ist seltsam: Sie klicken einmal, um das 4-Wege-Scrollen zu aktivieren, und klicken erneut, um es zu deaktivieren. Du kannst nicht halten und scrollen, was ich wollte. Ich habe ihre deinstalliert Software.

Ich habe den gleichen Trackball und die Lösung ist sehr elegant: Wenn Sie auf eine ausgewählte Schaltfläche klicken, wird der Ball selbst zu einem Scrollrad. Ich habe den großen rechten Knopf gewählt, den ich mit dem kleinen Finger drücke.

Dies ist sehr praktisch und es dauert nur wenige Tage, um sich daran zu gewöhnen.

Sie werden schnell feststellen, dass jedes Scrollrad (auf einer Maus oder einem Trackball) etwas Unbrauchbares ist. Vertrauen Sie mir, es lohnt sich ;-)

Vorteile:

• 2D Scrollen statt 1D -
• schnelleres und präziseres Scrollen als ein Rad
• bequemer für langes Scrollen (dank der Trägheit des Balls). Perfekt für Ihr Facebook-Beispiel.

Ich kann nicht mehr ohne sie leben.

Konfigurieren, dass unter jedem Linux-Betriebssystem ist nicht schwer. Sie müssen nur ein /etc/X11/xorg erstellen.conf-Datei (siehe meine Konfiguration hier: Konfigurieren Sie einen Trackball unter Linux, ohne Xorg zu bearbeiten.conf )

Weitere Details finden Sie hier: https://help.ubuntu.com/community/Logitech_Marblemouse_USB

Unter Windows habe ich keine Erfahrung, aber ich denke, ein Konfigurationstool wird mit dem Trackball geliefert.

Es gibt eine einfache 100-Zeilen-C++ - Alternative, die den AutoHotkey-Lösungen sehr ähnlich ist, dh

• vertikale / horizontale Scrollrad-Ereignisse senden, indem Sie den Trackball bewegen, während Sie eine der X-Tasten halten und
• mittlerer Klick beim Drücken und Loslassen einer X-Taste, ohne den Trackball zu bewegen.

Https://github.com/Seelge/TrackballScroll

Bearbeiten: Neuere Versionen bieten ein Systray-Symbol, arbeiten unter Windows 10 und basieren auf C#.

Sie könnten das Marble Mouse Scroll Wheel ausprobieren, das speziell für diese Maus entwickelt wurde:

Marble Mouse Scroll Wheel, oder nur Marble Scroll, ist ein kleines Programm entwickelt, um ein Scrollrad auf jedem Trackball oder Maus zu simulieren, ohne ein. Es wurde speziell für die Logitech Marble Mouse entwickelt, aber kann mit jeder Standardmaus oder Trackball arbeiten. Es ist entworfen für Windows 2000 und höher.

Marble Scroll ist ein Ersatz für Logitechs Autoscroll und Universal Scroll-Funktionen; weder richtig emulieren ein echtes Scrollrad und beide haben Einschränkungen und Mängel.

Marble Scroll funktioniert mit jeder Maus oder Trackball und erfordert keine Logitechs SolLwert-oder MouseWare-Treiber installiert werden.

Eigenschaften

• Fügen Sie einer Maus mit mehr als zwei Tasten ein Scrollrad hinzu
• Kompatibilität mit den meisten Anwendungen, die ein Scrollrad unterstützen (für jede Art von Eingabe)
• Verstellbar Beschleunigung
• Einstellbarer Bildlaufabstand (pro "Schritt" - siehe unten)
• Stufenloses Scrollen, um ein echtes Mausrad zu simulieren
• Schnelle links / rechtshänder modus switcher
• Schnelles Aktivieren / Deaktivieren durch Klicken auf das Tray-Symbol
• Klein und leicht auf Systemressourcen

Die Website des Produkts scheint derzeit nicht verfügbar zu sein, aber hier ist eine Kopie des Textes der Site auf Archive.org.

Ein Downloadlink ist hier.

Hier ist das AutoHotKey-Skript, das ich benutze. Sie scrollen, indem Sie die linke kleine Taste gedrückt halten und den Ball auf/ab rollen. Das Klicken auf die linke kleine Schaltfläche kehrt jedoch immer noch zurück. Es kann auch nach links/rechts scrollen, aber das war zu empfindlich für mich, daher ist es hier auskommentiert (der Block, der mit ;timesX := Abs(movedx) / 4 beginnt).

Ich fand die Originalversion unter http://www.autohotkey.com/board/topic/30816-simulate-scroll-wheel-using-right-mouse-button/. Ich habe meine Version dort als anotherperson8923.

$*XButton1::
Hotkey, $*XButton1 Up, XButton1up, off
;KeyWait, XButton1, T0.4
;If ErrorLevel = 1
;{
   Hotkey, $*XButton1 Up, XButton1up, on
   MouseGetPos, ox, oy
   SetTimer, WatchTheMouse, 5
   movedx := 0
   movedy := 0
   pixelsMoved := 0
;   TrayTip, Scrolling started, Emulating scroll wheel
;}
;Else
;   Send {XButton1}
return

XButton1up:
Hotkey, $*XButton1 Up, XButton1up, off
SetTimer, WatchTheMouse, off
;TrayTip
If (pixelsMoved = 0)
{
    ;The mouse was not moved, send the click event
    ; (May want to make it PGUP or something)
    Send {XButton1}
    Send {XButton1Up}
}
return

WatchTheMouse:
MouseGetPos, nx, ny
movedx := movedx+nx-ox
movedy := movedy+ny-oy

pixelsMoved := pixelsMoved + Abs(nx-ox) + Abs(ny-oy)

;timesX := Abs(movedx) / 4
;ControlGetFocus, control, A
;Loop, %timesX%
;{
;    If (movedx > 0)
;    {
;        SendMessage, 0x114, 1, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx - 4
;    }
;    Else
;    {
;        SendMessage, 0x114, 0, 0, %control%, A ; 0x114 is WM_HSCROLL
;        movedx := movedx + 4
;    }
;}

timesY := Abs(movedy) / 4
Loop, %timesY%
{
    If (movedy > 0)
    {
        Click WheelDown
        movedy := movedy - 4
    }
    Else
    {
        Click WheelUp
        movedy := movedy + 4
    }
}   

MouseMove ox, oy
return

Es ist eine Schande, dass Logitech keine Scrollradsimulation implementiert hat. Ihr Treiber verspricht eine Funktion, dies zu tun, aber es funktioniert nicht für alle Anwendungen, wodurch es ziemlich nutzlos. Sie waren so nah an der Schaffung der perfekten Maus! :s -

Die einzige Problemumgehung, die ich gefunden habe, ist die Verwendung eines AutoHotkey - Skripts dafür. Damit können Sie die winzigen linken / rechten Tasten nach oben und unten scrollen lassen. Es funktioniert perfekt, aber es ist ein echter Aufwand, um es zu konfigurieren: Sie müssen lernen, die AutoHotkey Grundlagen zuerst. Wenn Sie sich dafür entscheiden, ist hier mein AutoHotkey-Skript. Es ist eine Adaption von Jerbos ursprünglichem Skript. Ein einzelner Klick beginnt mit einem normalen Tempo zu scrollen, aber ein Doppel-oder Dreifach-Klick beginnt schneller zu scrollen.

; This script remaps the two small buttons on a Logitech Trackman® Marble® Mouse
; to act as scroll up and scroll down

global lastXButton1ClickTime := 0
global nrSubsequentXButton1Clicks := 0

ScrollTheWheel(direction, scrollKey)
{
    now := A_TickCount
    timeSinceLastClick := now - lastXButton1ClickTime 
    lastXButton1ClickTime := now
    if (timeSinceLastClick < 300)
    {
        nrSubsequentXButton1Clicks := nrSubsequentXButton1Clicks + 1
    }
    else
    {
        nrSubsequentXButton1Clicks := 1
    }        

    sleepingFraction := 5

    if (nrSubsequentXButton1Clicks <= 1)
        scrollSpeed := 30
    if (nrSubsequentXButton1Clicks == 2)
        scrollSpeed := 15
    if (nrSubsequentXButton1Clicks >= 3)
        scrollSpeed := 5

    timeSlept := scrollSpeed

    loop 
    {
        if (direction == 1) ; Scroll down
        {
            static downKeyState
            if (scrollKey == 0) 
                GetKeyState, downKeyState, XButton1, P
            else
                GetKeyState, downKeyState, PgDn, P

            if downKeyState = U ; The key has been released, so break out of the loop
               break

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelDown}
                timeSlept = 0                
            }
        }
        else ; Scroll up
        {
            static upKeyState
            if (scrollKey == 0)
                GetKeyState, upKeyState, XButton2, P
            else
                GetKeyState, upKeyState, PgUp, P

            if upKeyState = U ; The key has been released, so break out of the loop
               break            

            if (timeSlept >= scrollSpeed)
            {
                Send {WheelUp}
                timeSlept = 0                
            }
        }   

        Sleep, sleepingFraction
        timeSlept := timeSlept + sleepingFraction
    }    
}

XButton2::
    ScrollTheWheel(0, 0)
    return
XButton1::
    ScrollTheWheel(1, 0)
    return
!PgUp::
    ScrollTheWheel(0, 1)
    return
!PgDn::
    ScrollTheWheel(1, 1)
    return

Ich habe gerade eine Logitech Marble Mouse bekommen und hatte auch das Problem des Scrollens. Also habe ich dieses Skript auf AutoHotkey erstellt. Der linke Xbutton ermöglicht das Scrollen, was bedeutet, dass Sie nach unten vertikal und horizontal mit dem Ball scrollen und sich im Browser mit den linken und rechten Tasten vorwärts und rückwärts bewegen können. Die rechte Xbutton hat die gleiche Aktion wie die mittlere Taste.

Im auf Windows 7.

#SINGLEINSTANCE FORCE  
GLOBAL status := "basic"
GLOBAL cnt_x
GLOBAL cnt_y

XButton2::MButton

$*XButton1::
    status := "scroll"
    cnt_x := 0
    cnt_y := 0
    MOUSEGETPOS, st_x, st_y
    SETTIMER, _scroll, 30
RETURN

$*XButton1 UP::
    status := "basic"
    SETTIMER, _scroll, OFF
RETURN

_scroll:
    MOUSEGETPOS, cur_x, cur_y
    MOUSEMOVE, st_x, st_y

IF(abs(cur_x-st_x) > abs(cur_y-st_y)) {
    cnt_x := cnt_x + (cur_x-st_x)
    ControlGetFocus, control, A 
    IF (cnt_x > 7) {
        cnt := floor(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 0, 0, %control%, A
        }
        cnt_x := cnt_x - 8*floor(cnt_x / 8)
    } ELSE IF (cnt_x < -7) {
        cnt := -ceil(cnt_x / 8)
        LOOP, %cnt% {
            SendMessage, 0x114, 1, 0, %control%, A
        }
        cnt_x := cnt_x - 8*ceil(cnt_x / 8)
    }
} ELSE {
    IF (cur_y >= st_y) {
        cnt_y := cnt_y + (cur_y-st_y)**1.2
    } ELSE {
        cnt_y := cnt_y -(st_y-cur_y)**1.2
    }   
    IF (cnt_y > 7) {
        cnt := floor(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelUp
        }
        cnt_y := cnt_y - 8*floor(cnt_y / 8)
    } ELSE IF (cnt_y < -7) {
        cnt := -ceil(cnt_y / 8)
        LOOP, %cnt% {
            CLICK WheelDown
        }
        cnt_y := cnt_y - 8*ceil(cnt_y / 8)
    }
}   
RETURN

$*LButton::
    IF (status = "basic") {
        CLICK DOWN Left
    } ELSE IF (status = "scroll") {
        SEND {Browser_Back}
    }
RETURN

$*LButton UP::
    IF (status = "basic") {
        CLICK UP Left
    }
RETURN

$*RButton::
    IF (status = "basic") {
        CLICK DOWN Right
    } ELSE IF (status = "scroll") {
        SEND {Browser_Forward}
    }
RETURN

$*RButton UP::
    IF (status = "basic") {
        CLICK UP Right
    }
RETURN

Eine weitere Lösung für Windows 7, die das Scrollen in allen Anwendungen, einschließlich Internet Explorer, ermöglicht:

1. Installation AutoHotKey.
2. Retten dieses Skript als scroll.ahk für den Desktop.
3. Rechtsklick auf scroll.ahk.
4. Wählen Sie Skript Ausführen.
5. Bestätigen Sie, wenn Sie dazu aufgefordert werden.

Dadurch wird das Halten der kleinen rechten Taste beim Bewegen des Trackballs vertikal verschoben. Die kleine linke Taste ist die Zurück-Taste.

In falls der Link zu Erik Elmores Code verschwindet, hier ist es:

;;
;; Emulate_Scrolling_Middle_Button.ahk
;; Author: Erik Elmore <[email protected]>
;; Version: 1.1 (Aug 16, 2005)
;;
;; Enables you to use any key with cursor movement
;; to emulate a scrolling middle button.  While
;; the TriggerKey is held down, you may move the
;; mouse cursor up and down to send scroll wheel
;; events.  If the cursor does not move by the
;; time the TriggerKey is released, then a middle
;; button click is generated.  I wrote this for my
;; 4-button Logitech Marble Mouse (trackball),  
;; which has no middle button or scroll wheel.
;;

;; Configuration

;#NoTrayIcon

;; Higher numbers mean less sensitivity
esmb_Threshold = 7

;; This key/Button activates scrolling
esmb_TriggerKey = XButton2

;; End of configuration

#Persistent
CoordMode, Mouse, Screen
Hotkey, %esmb_TriggerKey%, esmb_TriggerKeyDown
HotKey, %esmb_TriggerKey% Up, esmb_TriggerKeyUp
esmb_KeyDown = n
SetTimer, esmb_CheckForScrollEventAndExecute, 10
return

esmb_TriggerKeyDown:
  esmb_Moved = n
  esmb_FirstIteration = y
  esmb_KeyDown = y
  MouseGetPos, esmb_OrigX, esmb_OrigY
  esmb_AccumulatedDistance = 0
return

esmb_TriggerKeyUp:
  esmb_KeyDown = n
  ;; Send a middle-click if we did not scroll
  if esmb_Moved = n
    MouseClick, Middle
return

esmb_CheckForScrollEventAndExecute:
  if esmb_KeyDown = n
    return

  MouseGetPos,, esmb_NewY
  esmb_Distance := esmb_NewY - esmb_OrigY
  if esmb_Distance
    esmb_Moved = y

  esmb_AccumulatedDistance := (esmb_AccumulatedDistance + esmb_Distance)
  esmb_Ticks := (esmb_AccumulatedDistance // esmb_Threshold) ; floor divide
  esmb_AccumulatedDistance := (esmb_AccumulatedDistance - (esmb_Ticks * esmb_Threshold))
  esmb_WheelDirection := "WheelDown"
  if (esmb_Ticks < 0) {
    esmb_WheelDirection := "WheelUp"
    esmb_Ticks := (-1 * esmb_Ticks)
  }

  ;; Do not send clicks on the first iteration
  if esmb_FirstIteration = y
    esmb_FirstIteration = n
  else {
    Loop % esmb_Ticks {
      MouseClick, %esmb_WheelDirection%
    }
  }

  MouseMove,esmb_OrigX,esmb_OrigY,0
return

Abhängig von Ihrem Betriebssystem können Sie möglicherweise eine der Schaltflächen so konfigurieren, dass das Scrollen durch Bewegen des Zeigers bei gedrückter Position aktiviert wird. ZB das folgende Skript aktiviert dies auf Taste 10 meiner Maus (die Schaltfläche "obere Mitte" des Logitech MX310):

#!/bin/sh
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 290 10
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 286 1
xinput set-prop "Logitech USB-PS/2 Optical Mouse" 287 6 7 4 5

Es gibt solche Marmormaus (Mäuse), die ein Scrollrad enthalten. Andernfalls sieht es so aus, als ob eine App oder ein Skript für eine Maus mit nicht Rädern erforderlich wäre, zusammen mit der Verwendung einer der Schaltflächen, um eine Bildlauffunktion auszuführen (die Sie in einem Kommentar zu einer anderen Antwort als keine akzeptable Lösung angegeben haben).

Also " Warum das Rad neu erfinden?"ist ein gutes Sprichwort in diesem Fall.

In diesen Beispielen ist das Element physisch installiert und es stehen viele Typen zur Auswahl. Unten sind zwei Beispiele und Stile.

Oder so ähnlich: Adesso

Eine einfache (und ich wage es zu sagen) Lösung besteht darin, die Funktion des Scrollens auf Ihren linken Rand zu setzen.

Dies könnte erreicht werden, indem Sie eine Maus mit der linken Hand verwenden/ indem Sie eine Tastatur mit einem eingebauten Scrollrad am linken Rand verwenden / indem Sie den Tasten einer programmierbaren Tastatur mit einem Programm wie Mkey Scrollfunktionen zuweisen (http://www.seriosoft.org/en/index.php).

Warum denke ich, dass dies ergonomischer ist - weil dieser Ansatz die Spannung gleichmäßiger verteilt auf beiden Händen. (Mehr dazu: http://capsoff.org/checklist).

Ich bin auf Windows7 und benutze den Kensington Orbit Optical Trackball ohne Scrollring - es ist ein Zwei-Tasten-Trackball, ohne die X-Tasten, die von den meisten AHK-Skripten und-Anwendungen benötigt werden von anderen darauf hingewiesen.

Jedoch MouseImp funktioniert für mich unter Windows7. ES ist konfigurierbar, aber ich habe es für right-click + roll eingerichtet, um mir einen Bildschirm zum Scrollen zu geben. Es ist eher wie ein Ziehen, also bewegt sich der Zeiger, und Sie haben jeweils nur einen Bildschirm [update: Die Bildlaufrate ist konfigurierbar, so kann es mehr als "eine Seite"sein].

Gleichzeitig wurde Kensington ' s TrackballWorks so konfiguriert, dass ich auf left-click + right-click nach unten scrollen kann. Leider kann es dann nicht immer eine Seite nach oben scrollen (die eine oder andere).

Dies ist nicht ein Produkt stecken - es ist genau das, was ich gefunden habe arbeiten mit diesem Modell/Typ der trackball - .

Vorbehalt: Sie sind ständig rechts und links klicken, und dies kann zu verwirrend führen, und Links werden followed / js-aktiviert, wenn Sie nur stop scrolling. :::seufz:::

Ich hab genau ein orbit wireless trackball von kensington, ist es ziemlich erstaunlich. Sie haben den Ball, Sie haben beide Tasten auf jeder Seite und Sie haben eine Art Kreis außerhalb des Trackballs, der es ermöglicht, die Seite nach oben oder unten zu scrollen. Es funktioniert wirklich und ich verwende es unter Windows und Mac OSX.

Ich habe vor einiger Zeit mit AutoHotkey etwas dafür gemacht und dachte, ich würde es auch hier teilen: Mausrad Emulator

Dies emuliert das Scrollen des Mausrads, indem die Maus bewegt wird, während die linke und rechte Maustaste gedrückt gehalten wird.

Sie können auch einen mittleren Klick emulieren, indem Sie gleichzeitig auf die linke und rechte Maustaste klicken.

Ein weiterer Trackman Marmor Benutzer hier.

Ich verwende X-Mouse Button Control für die Bildlaufemulation. Diese Feature-Implementierung ist dort (noch?), aber es ist viel verwendbarer als die Logitech-Implementierung in ihrer eigenen SetPoint™ - Software.

Ich empfehle XMBC jedem, der sich nicht mit AutoHotkey anlegen möchte und nach etwas sucht, das einfach funktioniert.

Zwei nicht konventionelle Optionen

• Verwenden Sie zusätzlich zum Trackball ein Apple Magic Trackpad. (Dies ist meine aktuelle Lösung) http://www.apple.com/magictrackpad/

• Kaufen Sie einen Leapmotion-Controller und verwenden Sie ihn zusätzlich zum Trackball. Winken Sie mit der Hand vor dem Gerät, um nach oben und unten zu scrollen. https://www.leapmotion.com/product

Bildnachweis http://www5.pcmag.com/media/images/393268-leap-motion-controller.jpg

(Noch) Eine andere Lösung ist die Verwendung dieses einfachen Programms namens MarbleScroll für Logitech Trackman Marble.

Einige Details über MarbleScroll:

• funktioniert auf Windows XP, Vista, 7, 8, 8.1, 10, ...
• build für. NET Framework 4.5, aber es sollte auf jedem anderen kompilieren, wenn Sie es in project source
• kompiliert für Rechtshänder Maus, aber es funktioniert auch für Linkshänder.
• wird in der Taskleiste ausgeführt, wo Sie es bei Bedarf schließen können zu
• vertikales und horizontales Scrollen mit Zurück-Taste + Marmorbewegung
• zurück taste ohne marmor bewegung erzeugt normalen zurück betrieb
• scrollt die Fenster unter dem Mauszeiger, ohne sie zu fokussieren

Der Autor teilte sogar den Quellcode sowie das Visual Studio-Projekt.

Beachten Sie, dass es mit SetPoint kompatibel ist.